Found in 33 Minutes: How to Triage Internet Scanners by Behaviour, Not by What They Call Themselves
The first request reached my new server 33 minutes after it went online. 24 scanners named themselves, and several that claimed to be "research" collected secrets like any attacker. Here's how to triage scanner traffic by behaviour in Splunk and Sentinel, auto-close the benign ones safely, and find your own new exposures before the scanners do with CrowdStrike and Defender for Endpoint.
Part of my honeypot detection series. Org A runs Splunk with CrowdStrike Falcon. Its Falcon queries use Event Search field names; on raw FDR data, apply the normalisation macro first. Org B runs Microsoft Sentinel with Defender for Endpoint. The web-layer KQL ran against the honeypot's real logs. The endpoint queries are templates for your environment.
1. What Hit the Server
The container started at 05:01 UTC on 22 October. The first request from the internet arrived 33 minutes later. In the first 24 hours, 86 addresses sent 666 requests. Nobody had published the address anywhere. Scanners found it because they scan everything, all the time.
24 scanners named themselves in their User-Agent, usually with a link explaining the scan. Together they sent 831 requests from 417 addresses, only 7.9% of external traffic. The rest didn't say who they were.
For a SOC, this traffic is mostly noise, and it's tempting to auto-close anything that says "research". This post is about why that's a mistake, and what to key on instead.
2. Who Came
| Scanner | What it is | Requests | IPs | Days seen | First seen (UTC) | After container start | Top paths |
|---|---|---|---|---|---|---|---|
| Censys | internet search engine | 231 | 89 | 18 | 2026-10-23 16:08 | 35.1 h | /, /favicon.ico, /info.php |
| Infrawatch | internet search engine | 144 | 119 | 18 | 2026-10-22 23:11 | 18.2 h | /, /favicon.ico, /mcp/ |
| Palo Alto Networks Cortex Xpanse | attack-surface management | 109 | 98 | 19 | 2026-10-22 23:18 | 18.3 h | /, /.well-known/security.txt, /yawhpsiabsent |
| Nokia (GenomeCrawler) | internet mapping | 109 | 10 | 11 | 2026-10-23 05:27 | 24.4 h | /, /manage/account/login, /admin/index.html |
| ForestEngine | internet search engine | 74 | 36 | 19 | 2026-10-22 14:12 | 9.2 h | /, /favicon.ico |
| Modat | internet search engine | 20 | 9 | 10 | 2026-10-23 03:30 | 22.5 h | /, /favicon.ico |
| Odin | internet search engine | 17 | 7 | 5 | 2026-10-23 05:15 | 24.2 h | /, /sdk, /HNAP1 |
| mrtscan | unknown, names a cloud region | 33 | 11 | 11 | 2026-10-23 21:10 | 40.1 h | / |
| visionheight.com | attack-surface scanning | 26 | 4 | 13 | 2026-10-22 19:47 | 14.8 h | /, /robots.txt |
| CyberConvoy Scout | attack-surface scanning | 11 | 3 | 11 | 2026-10-23 13:15 | 32.2 h | / |
| Apcosys | internet scanning | 11 | 5 | 7 | 2026-10-23 14:14 | 33.2 h | /robots.txt, /, /favicon.ico |
| IVRE (masscan) | open-source tool | 8 | 5 | 8 | 2026-10-23 13:20 | 32.3 h | /admin/config.php, / |
| Ruhr-Universität Bochum | academic research | 7 | 1 | 1 | 2026-10-22 15:29 | 10.5 h | / |
| InternetMeasurement | internet measurement | 6 | 6 | 6 | 2026-10-22 06:08 | 1.1 h | / |
| FH Münster | academic research | 6 | 1 | 2 | 2026-10-28 18:41 | 6.6 days | /, /app-config.js, /dicom-web/studies?0020000D=2.25.83961957171485309472578960013521734519&00080020=30000101 |
| Netcraft | internet survey | 1 | 1 | 1 | 2026-11-05 20:52 | 14.7 days | / |
| ipip.net | internet scanning | 2 | 2 | 2 | 2026-10-22 16:02 | 11.0 h | / |
| FlowIQ Labs | internet scanning | 2 | 2 | 2 | 2026-10-24 19:18 | 2.6 days | / |
| Keydrop.io / onlyscans | internet scanning | 6 | 3 | 3 | 2026-10-27 17:34 | 5.5 days | /.env, /.git/config |
| tchelebi | internet scanning | 2 | 1 | 2 | 2026-10-28 19:52 | 6.6 days | / |
| ipbase | internet scanning | 1 | 1 | 1 | 2026-11-03 09:02 | 12.2 days | / |
| InternetData.io | internet scanning | 1 | 1 | 1 | 2026-11-05 07:26 | 14.1 days | / |
| URSA | unknown | 3 | 1 | 1 | 2026-10-22 23:10 | 18.1 h | /, /api/export-auth |
| Synthient | research claim | 1 | 1 | 1 | 2026-11-01 22:09 | 10.7 days | hxxp://probe.invalid/ |
The big internet search engines (Censys, Infrawatch, Palo Alto's Xpanse) arrived within a day or two and came back almost daily. They mostly fetch /, the favicon and security.txt, which is what their indexes show.
Then there are the ones that call themselves research and behave like attackers:
| User-Agent | Requests | IPs | What it asked for |
|---|---|---|---|
Mozilla/5.0 (compatible; research-scan/1.0) | 38 | 1 | /, /@vite/client, /.git/HEAD, /.env, /.env~ |
Mozilla/5.0 (compatible; Scanner/1.0) | 21 | 19 | /.git/config |
php2shell-scan/3.1 (authorized-security-assessment) | 37 | 1 | /, /phpinfo.php, /info.php, /test.php, /phpversion.php |
grok-fp/1.0 (authorized research) | 1 | 1 | / |
Mozilla/5.0 (compatible; opendir-scanner/1.0) | 4 | 1 | / |
Mozilla/5.0 (X11; Linux x86_64) HighPerfScanner/10G | 4 | 4 | / |
research-scan/1.0 needed four seconds for this list:
/
/@vite/client
/.git/HEAD
/.env
/.env~
/.env.local
/.env.bak
/.env.old
/.env.zip
/backup.tar.gz
/.git-credentials
/.env.prod
/.env.save
/backup.zip
/site.zip
/.env.production.local
/.git/config
/www.zip
...
.env files, Git credentials, AWS keys, Docker registry credentials, Terraform variables and site backups. No link, no contact, no opt-out, and nothing in that list measures anything. It collects secrets. The name is a claim, not an identity (T1036.005 Match Legitimate Name).
3. Pyramid of Pain
| Level | Indicator | What I'd do with it |
|---|---|---|
| IP addresses | Censys's and Xpanse's published ranges | Reasonable for allowlisting published ranges of real search engines, as long as you still watch what they request. |
| User-Agent | research-scan/1.0, Scanner/1.0, authorized-security-assessment | Never trust it for suppression. It costs the attacker nothing to type. |
| Behaviour | What the client asks for: public pages, or secrets and exploits? | This is the line between a census and an attack. Key your triage on it. |
4. Detections
For Org B I've parsed the honeypot's nginx log into a WebAccess function. For Org A I've used the CIM Web data model.
let WebAccess = Syslog
| where SyslogMessage startswith "php_http: "
| extend j = parse_json(substring(SyslogMessage, 10))
| project TimeGenerated, DestHost = Computer, SrcIp = tostring(j.client), Method = tostring(j.method), Request = tostring(j.request),
Url = tostring(j.uri), Status = toint(j.status), BytesOut = toint(j.bytes_out),
UserAgent = tostring(j.user_agent), ContentType = tostring(j.content_type), Body = tostring(j.body);
W1. "Research" names that hunt secrets or send exploits (T1036.005)
Org B Tested: five User-Agents. Scanner/1.0 (23 of 23 requests hostile, from 21 addresses), research-scan/1.0 (18 of 38), Nokia's GenomeCrawler (9 of 119, all router and VPN login pages), Keydrop.io (6 of 6), and plain research (4 of 4).
let SecretOrExploit = @"(?i)(/\.env|\.git/|/\.aws/|credentials|wp-config\.|\.sql|eval-stdin|invokefunction|allow_url_include|/cgi-bin/|\$\{jndi|/\.ssh/)";
WebAccess
| where UserAgent matches regex @"(?i)(research|scan|census|bot|crawler|measurement|security|authori[sz]ed)" and UserAgent !has "Googlebot"
| summarize Requests = count(), Sources = dcount(SrcIp),
Hostile = countif(Url matches regex SecretOrExploit or Body matches regex SecretOrExploit) by UserAgent
| extend HostilePct = round(100.0 * Hostile / Requests, 0)
| where Hostile > 0
| order by Hostile desc
Org A
| tstats count from datamodel=Web by Web.http_user_agent Web.url Web.src
| rename Web.* as *
| regex http_user_agent="(?i)(research|scan|census|bot|crawler|measurement|security|authori[sz]ed)"
| eval hostile=if(match(url, "(?i)(/\.env|\.git/|/\.aws/|credentials|wp-config\.|\.sql|eval-stdin|invokefunction|allow_url_include|/cgi-bin/|\$\{jndi|/\.ssh/)"), count, 0)
| stats sum(count) as requests sum(hostile) as hostile dc(src) as sources by http_user_agent
| eval hostile_pct=round(100*hostile/requests,0)
| where hostile > 0
| sort - hostile
The ratio is the useful number. A real census sits near 0% hostile. Anything near 100% is an attacker wearing a lanyard. Use this to decide which scanner names go on your benign list, and which go on a block list.
W2. A "benign" scanner that starts misbehaving
Once you have a benign list, the risk is that someone hides behind it. This rule fires when a client matching a benign scanner token asks for secrets or sends an exploit:
Org B Tested with Censys, Infrawatch, Xpanse, GenomeCrawler, Odin, Modat, InternetMeasurement, ShadowServer, Onyphe and BitSight as the benign list: zero hits. The named scanners that publish opt-outs behaved like scanners.
// Watchlist "BenignScanners": SearchKey = UA token (e.g. "censys"), plus Owner and OptOutUrl columns
let BenignTokens = toscalar(_GetWatchlist("BenignScanners") | summarize make_list(tolower(SearchKey)));
let SecretOrExploit = @"(?i)(/\.env|\.git/|/\.aws/|eval-stdin|invokefunction|allow_url_include|\$\{jndi|constructor:constructor)";
WebAccess
| where tolower(UserAgent) has_any (BenignTokens)
| where Url matches regex SecretOrExploit or Body matches regex SecretOrExploit
| project TimeGenerated, SrcIp, UserAgent, Url
Org A
| tstats count from datamodel=Web by Web.src Web.http_user_agent Web.url
| rename Web.* as *
| lookup benign_scanners.csv ua_token AS http_user_agent OUTPUT owner ``` lookup with WILDCARD(ua_token) match_type ```
| where isnotnull(owner)
| regex url="(?i)(/\.env|\.git/|/\.aws/|eval-stdin|invokefunction|allow_url_include|\$\{jndi)"
| table src http_user_agent owner url count
With this rule in place, you can safely auto-close benign-scanner traffic in your other rules, because you'll hear about it the moment one of them stops behaving like a scanner. High severity: it means either a spoofed name or a scanner that changed what it does.
5. Endpoint: Beat the Scanners to Your Own Exposure
Censys found my server in under a day and a half, and the unnamed scanners found it in 33 minutes. You want to know about a new internet-facing service before either of them. Both EDRs see a process start listening on a port.
E1. New listening port on an internet-facing host
Org B Defender for Endpoint marks internet-facing devices (IsInternetFacing in DeviceInfo):
// Know about a new internet-facing service before the scanners do
let InternetFacing = DeviceInfo | where Timestamp > ago(1d) and IsInternetFacing == true | distinct DeviceId;
DeviceNetworkEvents
| where Timestamp > ago(1d)
| where ActionType == "ListeningConnectionCreated"
| where DeviceId in (InternetFacing)
| where LocalIP !in ("127.0.0.1", "::1")
| summarize FirstListen = min(Timestamp) by DeviceName, LocalPort, InitiatingProcessFileName
| join kind=leftanti (
DeviceNetworkEvents
| where Timestamp between (ago(30d) .. ago(1d)) and ActionType == "ListeningConnectionCreated"
| distinct DeviceName, LocalPort) on DeviceName, LocalPort
Org A Falcon's NetworkListenIP4 events, plus your own list of internet-facing hosts:
index=crowdstrike event_simpleName=NetworkListenIP4 earliest=-30d
| where LocalAddressIP4!="127.0.0.1"
| eval recent=if(_time >= relative_time(now(), "-1d"), 1, 0)
| stats min(_time) as first_seen max(recent) as seen_today by aid ComputerName LocalPort
| where seen_today=1 AND first_seen >= relative_time(now(), "-1d")
| lookup internet_facing_hosts.csv ComputerName OUTPUT exposure
| where exposure="internet"
A new port on an internet-facing host is either a change you knew about, or the start of the next incident: a debug server, a forgotten admin panel, an MCP server, a database. Medium severity, and route it to the team that owns the host.
For the outside view, both stacks have an external attack-surface product: Microsoft Defender External Attack Surface Management, and CrowdStrike Falcon Exposure Management. They do what Censys does, but for you. Feed their new-asset findings into the same SIEM queue.
6. When It Fires
- W1: decide per User-Agent. Near 0% hostile with a working opt-out link goes on the benign list. Near 100% goes on the block list at the WAF.
- W2: look at the source IP. If it isn't in the scanner's published ranges, it's spoofed, so block it and hunt for the same IP in other logs. If it is in the published ranges, contact the scanner's operator through their opt-out page.
- E1: confirm with the owner. If nobody expected it, close the port first and ask questions after. Org A Network-contain the host in Falcon if the service looks hostile. Org B Isolate the device in Defender if the service looks hostile.
7. Hardening
- Assume any new public IP is scanned within an hour. Deploy with the firewall already closed, and open only what you need.
- Publish
security.txt. The well-behaved scanners read it, and it gives researchers a way to report what they find. - Opt out of the scanners you don't want through their published pages, then let W2 tell you if any of them ignore it.
8. IOCs
| Type | Value | Context |
|---|---|---|
| Fake research | 129.213.151[.]234 (research-scan/1.0) | Secret-file collection in 4 seconds |
| Fake research | UA Scanner/1.0, 21 addresses | /.git/config only |
| Self-described "authorised" | php2shell-scan/3.1 (authorized-security-assessment) | Nobody authorised it here |